(声明：魏滔序原创，转贴请注明出处。)
         原文地址：http://blog.csdn.net/Modest/archive/2006/10/11/1330505.aspx?Pending=true
        下面贴出本工具中用到的关闭本地计算机共享目录的代码(与其相对应的创建共享的代码也整理出来一同贴上)，实际上用这个代码还可以关闭网络中其他计算机的共享目录，但要保证有足够的权限(至少可以通过网上邻居正常访问到对方计算机)。创建或删除本机的共享目录，用127.0.0.1就可以了。

代码如下：
Option Explicit
'共享类型
Private Const STYPE_ALL       As Long = -1
Private Const STYPE_DISKTREE  As Long = 0
Private Const STYPE_PRINTQ    As Long = 1
Private Const STYPE_DEVICE    As Long = 2
Private Const STYPE_IPC       As Long = 3
Private Const STYPE_SPECIAL   As Long = &H80000000
'共享权限
Private Const ACCESS_READ     As Long = &H1
Private Const ACCESS_WRITE    As Long = &H2
Private Const ACCESS_CREATE   As Long = &H4
Private Const ACCESS_EXEC     As Long = &H8
Private Const ACCESS_DELETE   As Long = &H10
Private Const ACCESS_ATRIB    As Long = &H20
Private Const ACCESS_PERM     As Long = &H40
Private Const ACCESS_ALL      As Long = ACCESS_READ Or ACCESS_WRITE Or ACCESS_CREATE Or ACCESS_EXEC Or ACCESS_DELETE Or ACCESS_ATRIB Or ACCESS_PERM
'共享信息
Private Type SHARE_INFO_2
    shi2_netname       As Long                             '共享名
    shi2_type          As Long                             '类型
    shi2_remark        As Long                             '备注
    shi2_permissions   As Long                             '权限
    shi2_max_uses      As Long                             '最大用户
    shi2_current_uses  As Long                             '
    shi2_path          As Long                             '路径
    shi2_passwd        As Long                             '密码
End Type

Private Declare Function NetShareAdd Lib "netapi32.dll" (ByVal ServerName As Long, ByVal level As Long, buf As Any, Parmerr As Long) As Long
Private Declare Function NetShareDel Lib "netapi32.dll" (ByVal ServerName As Long, ByVal ShareName As Long, ByVal dword As Long) As Long

'设置共享(返回0 为成功)
Public Function CreateShare(ByVal ServerName As String, ByVal SharePath As String, ByVal ShareName As String, Optional ByVal Password As String, Optional ByVal Remark As String) As Long
    Dim pRemark As Long
    Dim pPassword As Long
    Dim SHI2 As SHARE_INFO_2
  
    If Len(Remark) > 0 Then pRemark = StrPtr(Remark) '备注
    If Len(Password) > 0 Then pPassword = StrPtr(Password) '密码

    '初始化共享信息
    With SHI2
        .shi2_netname = StrPtr(ShareName)
        .shi2_path = StrPtr(SharePath)
        .shi2_remark = pRemark
        .shi2_type = STYPE_DISKTREE
        .shi2_permissions = ACCESS_ALL
        .shi2_max_uses = -1
        .shi2_passwd = pPassword
    End With

    '设置共享(用户名,共享类型,共享信息,)
    CreateShare = NetShareAdd(StrPtr(ServerName), 2, SHI2, 0)
End Function

'删除共享(返回0 表示成功)
Public Function DeleteShare(ByVal ServerName As String, ByVal ShareName As String) As Long
    DeleteShare = NetShareDel(StrPtr(ServerName), StrPtr(ShareName), 0)
End Function

最后声明一下：不得请将本代码用到任何能够给别人造成任何损失的场合。